' Verbindung zu ActiveX-Komponenten aufnehmen
set WSHShell = CreateObject("WScript.Shell")

' welche Dateiextension soll registriert werden?
ext = lcase(InputBox("Geben Sie die Dateiextension des Dateityps an, den Sie bei der Miniaturansicht registrieren lassen wollen!", "Miniaturansicht", "jpg"))
ext = Replace(ext, ".", "")
if KeyExists("HKCR\." + ext + "\") then
	prg = WSHShell.RegRead("HKCR\." + ext + "\")
	name = WSHShell.RegRead("HKCR\" + prg + "\")
	if KeyExists("HKCR\" + prg + "\shellex\{bb2e617c-0920-11d1-9a0b-00c04fc2d6c1}\") then
		' ist bereits registriert!
		antwort = MsgBox(ext + "-Dateien sind bereits registriert. Wieder abmelden?", vbYesNo + vbQuestion)
		mode = 1
		if antwort=vbYes then
			' wird wieder de-registriert...
			WSHShell.RegDelete "HKCR\" + prg + "\shellex\{bb2e617c-0920-11d1-9a0b-00c04fc2d6c1}\"
			mode = 0
		end if
	else
		' ist noch nicht registriert!
		antwort = MsgBox(ext + "-Dateien sind nicht bei der Miniaturansicht registriert. Registrieren?", vbYesNo + vbQuestion)
		mode = 0
		if antwort = vbYes then
			' wird registriert...
			WSHShell.RegWrite "HKCR\" + prg + "\shellex\{bb2e617c-0920-11d1-9a0b-00c04fc2d6c1}\", "{7376D660-C583-11d0-A3A5-00C04FD706EC}"
			mode = 1
		end if
	end if
else
	MsgBox ext + " ist mit keinem Programm verknüpft!", vbInformation
end if

if mode=1 then
	MsgBox ext + " ist jetzt bei der Miniaturansicht registriert!", vbInformation
else
	MsgBox ext + " ist NICHT MEHR bei der Miniaturansicht registriert!", vbInformation
end if

function KeyExists(key)
	' prüft, ob es einen Registry-Schlüssel gibt
	on error resume next
	RegRead = WSHShell.RegRead(key)
	if err<>0 then
		KeyExists=vbFalse
		err.clear
	else
		KeyExists=vbTrue
	end if
end function